AmazonLinux2023で最新のPerl(5.38)を動かしてみた話し

①Amazon Linux 2023での環境構築

ベースがFedoraベースなので、少々使えるコマンドが違う点がまず最初に直面する問題です

※GPTに協力してもらって、できるだけわかりやすい図を作ろうとしましたが、きっちり親子関係になってるわけでもないものも多く
（この影響を受けている、、、みたいなものが親子関係かというとそういうわけでもなかったり）
あくまでもイメージの共有という形で割り切りで

Amazon Linux用のものがないので（Amazon Linux2の時はExtra Packageがあったのでそちらで入れられた）、一見、Amazon Linux2023の元になってるFedora用のものがいけそうでしたが、欲してるライブラリが一致せずダメなようでした

RHEL用のものと互換性があるようなので、こちらで成功しました
（クラスメソッドさんの記事参考にさせていただきましたhttps://dev.classmethod.jp/articles/install-mysql-client-to-amazon-linux-2023/）

MySQLのバージョンアップ

Amazon Linux2023でMySQLに接続する時には、データベースのバージョンもそれにあわせる必用がありました
　Aurora2(MySQL5.7互換性）のサポート来年の10月には切れてしまうので、覚悟決めてバージョンアップもしていきましょう
　
MySQLのバージョンをあげた弊害ですが、今のところ、MySQLのデフォルトのキャラセットがutf8mb4になってるせいか、データベースがutf8のままだと、DBIの接続時にMalformed packetが出てしまうようでエラーを解消できなかったので、データベースをutf8mb4に変更し対策しました

wkhtmltopdfの問題

./packaging/build package-docker amazonlinux2023-x86_64 /root/wkhtmltopdf/

ImageMagick問題

その他

②最新の安定版のPerl5.38をインストール

5.32ももう、2年前なんですよね

なので、どうせやるなら、最も新しいPerlにしようってことで、5.38を入れることにしました。

Perlのバージョン切り替えについて

curl -LO https://www.cpan.org/src/5.0/perl-5.38.0.tar.gz
tar -xzvf perl-5.38.0.tar.gz
cd perl-5.38.0
./Configure -des -Dprefix=/usr/local/perl-5.38.0
make
sudo make install
sudo alternatives --install /usr/bin/perl perl /usr/local/perl-5.38.0/bin/perl 300

curl -LO https://www.cpan.org/src/5.0/perl-5.32.0.tar.gz
tar -xzvf perl-5.32.0.tar.gz
cd perl-5.32.0
./Configure -des -Dprefix=/usr/local/perl-5.32.0
make
sudo make install
sudo alternatives --install /usr/bin/perl perl /usr/local/perl-5.32.0/bin/perl 10

cpanm --reinstall -L /usr/local/perl-5.38.0/lib/site_perl/5.38.0 DBI

バージョンアップに伴う弊害

③Perlの新機能や、試してみたかった機能の検証

Perl5.38の新機能

#!/usr/bin/perl
use feature qw(class try);
no warnings qw(experimental::class experimental::try);
#----------------------------------
# 従業員クラス
class Employee {
  field $id :param;
  field $name :param;
  field $age :param;
  # カスタムコンストラクタ
  # 直後に呼ばれる。引数とかのチェックとか、初期化処理とか、コンストラクタのカスタマイズしたい時はここで制御する";
  ADJUST {
    die "Invalid employee ID format\n" unless $id =~ /^[A-Z0-9]+$/;
    
  }
  method get_id() {
    return $id;
  }
  method get_name() {
    return $name;
  }
  method set_name($new_name) {
    $name = $new_name;
  }
  method get_age() {
    return $age;
  }
  method set_age($new_age) {
    $age = $new_age;
  }
}

#----------------------------------
# マネージャークラス
class Manager :isa(Employee) {
  field $department :param;  # 部署名
}

package main;
try{
	my $employee = Employee->new(id=>"12345",name=>"Alice",age=>30);
	print "-----------Employee----------------\n";
	print "ID: ", $employee->get_id(), "\n";
	print "Name: ", $employee->get_name(), "\n";

	# 従業員の名前を変更
	$employee->set_name("Bob");
	print "New Name: ", $employee->get_name(), "\n";
	my $manager  = Manager->new(department=>'system',id=>"11111",name=>"MG",age=>50);
	print "-----------Manager----------------\n";
	print "ID: ", $manager ->get_id(), "\n";
	print "Name: ", $manager ->get_name(), "\n";
} catch ($e) {
	print $e."\n";
}

#!/usr/bin/perl
#----------------------------------
# 従業員クラス
package Employee;
{
	sub new {
		my ($class, %args) = @_;
		die "Invalid employee ID format\n" unless $args{id} =~ /^[A-Z0-9]+$/;
		my $self = {
			id   => $args{id},
			name => $args{name},
			age  => $args{age},
		};
		return bless $self, $class;
	}
	sub get_id {
		my $self = shift;
		return $self->{id};
	}
	sub get_name {
		my $self = shift;
		return $self->{name};
	}
	sub set_name {
		my ($self, $new_name) = @_;
		$self->{name} = $new_name;
	}
	sub get_age {
		my $self = shift;
		return $self->{age};
	}
	sub set_age {
		my ($self, $new_age) = @_;
		$self->{age} = $new_age;
	}
}

#----------------------------------
# マネージャークラス
package Manager;
{
	use base qw(Employee);
	sub new {
		my ($class, %args) = @_;
		my $self = $class->SUPER::new(%args);
		$self->{department} = $args{department};
		return $self;
	}
}

package main;
eval{
	my $employee = Employee->new(id=>"12345",name=>"Alice",age=>30);
	print "-----------Employee----------------\n";
	print "ID: ", $employee->get_id(), "\n";
	print "Name: ", $employee->get_name(), "\n";
	$employee->set_name("Bob");
	print "New Name: ", $employee->get_name(), "\n";

	my $manager  = Manager->new(department=>'system',id=>"11111",name=>"MG",age=>50);
	print "-----------Manager----------------\n";
	print "ID: ", $manager ->get_id(), "\n";
	print "Name: ", $manager ->get_name(), "\n";
};
if ($@) {
	print $@."\n";
}

PSGIの検証

長らくこういう、Webサーバ自身にプログラムの仕事を一緒にさせる方式が取られていて、より高速化させるために、FastCGIや、mod_perlなど、Webサーバのモジュールとして、より高速化するための手法が取られてきました。

その後、2009年くらいから、WSGIなどに触発され、PerlをWebサーバから分離させて動かす、PSGI（Perl Web Server Gateway Interface）という方法が登場してきました。

この方法により、Webサーバは、プログラムの実行から解放され、PSGIで動作するアプリケーションサーバとの仲介だけの専念できるようになれるため、マルチスレッドでリクエストを処理できるようになれます。

なかなか難しい概念なので、GPTと相談して、ランチタイムの定食屋さんに来るお客さんと受け皿となるテーブルで例えてみました

WebサーバがCGIを動かそうとすると、このような形で、混みあってる時でも、座席に1人しか通さない形になって、店内の座席を有効活用できない状態になります。
ただし、プライベートな空間を持てるようになれるので、スマホで操作してる画面の内容や、PCを開いて社外秘の情報なども気にせず過ごすことができます

次にCGIを動かさず、マルチスレッドで動かす場合です。
こちらは空いてるスペースにどんどん人を入れていくので、スペースを有効活用できます。
そのかわり、1人1人の空間は限られているので、個人情報などまわりに見られないよう、配慮が必要です。

今回の勉強会では、GPTの画像生成DALL-Eとの対話も楽しい時間でした

では、早速PSGIの応答速度を検証してみます

Starman

cpanm --reinstall -L /usr/local/perl-5.38.0/lib/site_perl/5.38.0 Starman

/usr/local/perl-5.38.0/lib/site_perl/5.38.0/bin/starman --listen :5000 performance_test.psgi

performance_test.psgi

use strict;
use warnings;
use Plack::Request;
use File::Temp qw/ tempfile /;
use Time::HiRes qw( gettimeofday tv_interval );

my $app = sub {
    my $env = shift;
    my $request = Plack::Request->new($env);

    my $start_time = [gettimeofday];

    # ループ処理のための変数を宣言
    my $total = 0;
    for (my $i = 0; $i < 10000; $i++) {
        $total += $i;
    }

    # ファイル書き込みと読み取り
    my ($fh, $filename) = tempfile();
    print $fh "Some data";
    seek $fh, 0, 0;
    my $file_content = <$fh>;
    close $fh;

    # メモリ使用量の計測
    my $memory_usage = `ps -o rss= -p $$`;

    my $end_time = [gettimeofday];
    my $elapsed = tv_interval($start_time, $end_time);

    return [ 200, ['Content-Type' => 'text/plain'], 
             ["Loop total: $total\nFile content: $file_content\nMemory Usage: ${memory_usage}KB\nElapsed time: ${elapsed}s"] ];
};

$app;

performance_test.cgi

#!/usr/bin/perl

use strict;
use warnings;
use CGI;
use File::Temp qw/ tempfile /;
use Time::HiRes qw( gettimeofday tv_interval );

my $q = CGI->new;
print $q->header('text/plain');

my $start_time = [gettimeofday];

# ループ処理の変数を宣言
my $total = 0;
for (my $i = 0; $i < 10000; $i++) {
    $total += $i;
}

# ファイル書き込みと読み取り
my ($fh, $filename) = tempfile();
print $fh "Some data";
seek $fh, 0, 0;
my $file_content = <$fh>;
close $fh;

# メモリ使用量の計測
my $memory_usage = `ps -o rss= -p $$`;

my $end_time = [gettimeofday];
my $elapsed = tv_interval($start_time, $end_time);

print "Loop total: $total\n";
print "File content: $file_content\n";
print "Memory Usage: ${memory_usage}KB\n";
print "Elapsed time: ${elapsed}s";

負荷テスト

ab -n 100 -c 10 https://xxxx.xxx.xxx/

psgi環境の結果

$ ab -n 100 -c 10 https://xxxx.xxx.xx/index.cgi
This is ApacheBench, Version 2.3 <$Revision: 1843412 $>
Copyright 1996 Adam Twiss, Zeus Technology Ltd, http://www.zeustech.net/
Licensed to The Apache Software Foundation, http://www.apache.org/

Benchmarking xxxx.xxx.xx (be patient).....done


Server Software:        Apache/2.4.56
Server Hostname:        xxxx.xxx.xx
Server Port:            443
SSL/TLS Protocol:       TLSv1.2,ECDHE-RSA-AES256-GCM-SHA384,2048,256
Server Temp Key:        X25519 253 bits
TLS Server Name:        xxxx.xxx.xx

Document Path:          /index.cgi
Document Length:        91 bytes

Concurrency Level:      10
Time taken for tests:   3.232 seconds
Complete requests:      100
Failed requests:        9
   (Connect: 0, Receive: 0, Length: 9, Exceptions: 0)
Total transferred:      24391 bytes
HTML transferred:       9091 bytes
Requests per second:    30.94 [#/sec] (mean)
Time per request:       323.156 [ms] (mean)
Time per request:       32.316 [ms] (mean, across all concurrent requests)
Transfer rate:          7.37 [Kbytes/sec] received

Connection Times (ms)
              min  mean[+/-sd] median   max
Connect:       91  197 144.7    130     806
Processing:    36   60  32.5     52     287
Waiting:       36   58  23.2     51     155
Total:        133  258 142.8    195     846

Percentage of the requests served within a certain time (ms)
  50%    195
  66%    258
  75%    299
  80%    357
  90%    438
  95%    566
  98%    842
  99%    846
 100%    846 (longest request)

cgi環境の結果

kikuta@kikuta:~$ ab -n 100 -c 10 https://xxxx.xxx.xx/performance_test.cgi
This is ApacheBench, Version 2.3 <$Revision: 1843412 $>
Copyright 1996 Adam Twiss, Zeus Technology Ltd, http://www.zeustech.net/
Licensed to The Apache Software Foundation, http://www.apache.org/

Benchmarking xxxx.xxx.xx (be patient).....done


Server Software:        Apache/2.4.56
Server Hostname:        xxxx.xxx.xx
Server Port:            443
SSL/TLS Protocol:       TLSv1.2,ECDHE-RSA-AES256-GCM-SHA384,2048,256
Server Temp Key:        X25519 253 bits
TLS Server Name:        xxxx.xxx.xx

Document Path:          /performance_test.cgi
Document Length:        91 bytes

Concurrency Level:      10
Time taken for tests:   6.886 seconds
Complete requests:      100
Failed requests:        13
   (Connect: 0, Receive: 0, Length: 13, Exceptions: 0)
Total transferred:      26399 bytes
HTML transferred:       9099 bytes
Requests per second:    14.52 [#/sec] (mean)
Time per request:       688.597 [ms] (mean)
Time per request:       68.860 [ms] (mean, across all concurrent requests)
Transfer rate:          3.74 [Kbytes/sec] received

Connection Times (ms)
              min  mean[+/-sd] median   max
Connect:      107  249 261.9    138    1321
Processing:   111  307  91.1    315     506
Waiting:       92  267  78.0    271     506
Total:        248  557 247.9    486    1552

Percentage of the requests served within a certain time (ms)
  50%    486
  66%    559
  75%    618
  80%    630
  90%    749
  95%   1291
  98%   1539
  99%   1552
 100%   1552 (longest request)

検証結果

総評